%% This file, part of the Makor2 system for typesetting Hebrew with Omega,
%% generates the archaic Babylonian vowels for Hebrew.

mode_setup;
designsize:=10pt#;
if unknown FontSize: FontSize := 10pt#; fi
FX# := FontSize *   0.075 / 2.4; % normalize to 10pt---AH
FY# := FontSize *   0.075 / 2.4;
%% At 10ot, FX#=FY#=.3125pt.
define_pixels (FX, FY);

mynib#:=3FX#;
define_pixels (mynib);
def picknib=pickup pencircle scaled mynib enddef;

beginchar(74, 10FX#, mynib#,0); % schwa
  z0=(0,h/2); z1=(w,y0);
  pickup penrazor xscaled h yscaled 0 rotated 90;
  draw z0--z1;
endchar;

beginchar(72, 5mynib#, 3mynib#, 0); % qamats
  z1=(.5mynib, h/2); z0=(w-.5mynib, h-.5mynib); z2=(x0, .5mynib);
  picknib; draw z0..{left}z1; draw z1{right}..z2;
endchar;

beginchar(71, 5mynib#, 3mynib#, 0); % patach
  z0=(w/2, h-.5mynib); z1=(.5mynib, .5mynib); z2=(w-.5mynib, y0);
  picknib;
  draw z0..{left}z1&z1{right}..z2;
endchar;

beginchar(66, 5mynib#, 5mynib#, 0); % `hatafpatah'
  h':=3*mynib;
  z0=(w/2, h'-.5mynib); z1=(.5mynib, .5mynib); z2=(w-.5mynib, y0);
  picknib;
  draw z0..{left}z1&z1{right}..z2;
  z3=(0, h-.5mynib); z4=(w,y3);
  pickup penrazor xscaled mynib yscaled 0 rotated 90; draw z3--z4;
endchar;

beginchar(69, 3mynib#, mynib#, 0); % tsere
  z0=(.5mynib, h/2); z1=(w-x0, y0); picknib;
  drawdot z0; drawdot z1;
endchar;

beginchar(68, mynib#, mynib#, 0); % hiriq
  z0=(.5w,.5h); picknib; drawdot z0;
endchar;

beginchar(73, mynib#, 3mynib#,0); % holam
  x0=x1=w/2; y0=.5mynib; y1=h-y0; picknib;
  drawdot z0; drawdot z1;
endchar;

beginchar(182, 10FX#, 5FY# + 2mynib#, 0); % another hiriq
  z0=(0,.5mynib); z1=(w,y0); pickup penrazor xscaled mynib yscaled 0 rotated 90;
  draw z0--z1;
  z2=(.5w, h-.5mynib); picknib; drawdot z2;
endchar;

beginchar(75, mynib#, 4.5mynib#,0); % qubuts
  x0=x1=.5w; y0=0; y1=h;
  pickup penrazor xscaled mynib yscaled 0;
  draw z0--z1;
endchar;

beginchar(70, 3mynib#, 3mynib#,0); % segol
  x0=y0=.5mynib; x0+x1=w; y0+y1=h;
  picknib; drawdot z0; drawdot z1;
endchar;

beginchar(85, 3mynib#, mynib#,0); %holam
  x0=y0=.5w; x1=x0; y0+y1=h; picknib;
  drawdot z0; drawdot z1;
endchar;

end.